home *** CD-ROM | disk | FTP | other *** search
/ The PC-SIG Library 10 / The PC-Sig Library - Shareware for the IBM PC and Compatibles (PC-SIG)(Tenth Edition Disks 1-2804)(1991).iso / PC_SIGCD / 22 / 4 / DISK2247.ZIP / CBASE101.ZIP / BTREE101.ZIP / INSTALL.BAT < prev    next >
DOS Batch File  |  1990-06-20  |  5KB  |  146 lines
  1. @echo off
  2. rem btree installation batch file-----------------------------------------------
  3. rem install.bat    1.4 - 90/06/20
  4.  
  5. rem ----------------------------------------------------------------------------
  6. rem NAME
  7. rem      install.bat - btree library installation batch file for MS-DOS
  8. rem
  9. rem SYNOPSIS
  10. rem      install model [x]
  11. rem
  12. rem DESCRIPTION
  13. rem     install.bat performs the installation of the btree library for
  14. rem     MS-DOS.  model specifies the memory model as one of the following.
  15. rem
  16. rem          s        small model
  17. rem          m        medium model
  18. rem          c        compact model
  19. rem          l        large model
  20. rem          h        huge model
  21. rem
  22. rem     The library file is named btreem.lib, where m would correspond
  23. rem     to the memory model of the library.
  24. rem
  25. rem     If specified, the second parameter causes the reference manual to
  26. rem     be extracted from the source code.  The reference manual is placed
  27. rem     in the file btree.man.
  28. rem
  29. rem SEE ALSO
  30. rem      makefile
  31. rem
  32. rem NOTES
  33. rem      This batch file is written for use with Borland Turbo C.  To
  34. rem      convert it for use with another compiler, make the following
  35. rem      modifications:
  36. rem           1. Replace \tc\include with the include directory used by
  37. rem              the new compiler.
  38. rem           2. Replace \tc\lib with the library directory used by the
  39. rem              new compiler.
  40. rem           3. Replace tcc with the command to invoke the compiler being
  41. rem              used, replacing the switches also, if necessary.  Below
  42. rem              are listed the Turbo C switches used and their meanings.
  43. rem                   -O        jump optimization
  44. rem                   -G        speed optimization
  45. rem                   -c        compile but don't link
  46. rem                   -A        ANSI keywords only
  47. rem                   -C-       no nested comments
  48. rem                   -m        memory model
  49. rem           4. The command to build the library archive from the object
  50. rem              modules may vary more drastically.  Turbo C uses the tlib
  51. rem              command with what is called a response file.  This
  52. rem              response file, btree.rsp, contains a list of all the
  53. rem              object modules in the library.
  54. rem
  55. rem ----------------------------------------------------------------------------
  56.  
  57. rem verify arguments------------------------------------------------------------
  58. if "%1" == "s" goto arg1
  59. if "%1" == "m" goto arg1
  60. if "%1" == "c" goto arg1
  61. if "%1" == "l" goto arg1
  62. if "%1" == "h" goto arg1
  63. echo Usage:  install model [x]
  64. echo Valid values for model are s (small), m (medium), c (compact),
  65. echo   l (large), and h (huge).  Model must be lower case.
  66. echo If x is specified, the reference manual will be extracted.
  67. goto end
  68. :arg1
  69.  
  70. if "%2" == "" goto arg2
  71. if "%2" == "x" goto arg2
  72. echo Usage:  install model [x]
  73. echo Invalid second argument.  Valid value is lowercase x.
  74. :arg2
  75.  
  76. if "%3" == "" goto arg3
  77. echo Usage:  install model [x]
  78. echo Too many arguments specified.
  79. :arg3
  80.  
  81. rem check if blkio installed----------------------------------------------------
  82. if exist \tc\include\blkio.h goto blkio
  83. echo The blkio library must be installed first.
  84. goto end
  85. :blkio
  86.  
  87. rem extract the reference manual------------------------------------------------
  88. if not "%2" == "x" goto skipman
  89. echo Extracting reference manual into btree.man.
  90. if not exist btree.man goto man
  91. echo btree.man exists.  ^C to exit, any other key to continue.
  92. pause
  93. :man
  94. if not exist tmp goto tmp
  95. echo tmp exists.  ^C to exit, any other key to continue.
  96. pause
  97. :tmp
  98. echo on
  99. type btree.h | manx -c > btree.man
  100. copy btclose.c/a+btcreate.c+btcursor.c+btdelcur.c+btdelete.c+btfirst.c tmp
  101. type tmp | manx -c >> btree.man
  102. copy btfix.c/a+btgetcur.c+btgetk.c+btgetlck.c+btinsert.c+btkeycmp.c tmp
  103. type tmp | manx -c >> btree.man
  104. copy btkeycnt.c/a+btkeysiz.c+btlast.c+btlock.c+btnext.c+btopen.c tmp
  105. type tmp | manx -c >> btree.man
  106. copy btprev.c/a+btsearch.c+btsetbuf.c+btsetcur.c+btsetvbu.c+btsync.c tmp
  107. type tmp | manx -c >> btree.man
  108. del tmp
  109. @echo off
  110. :skipman
  111.  
  112. rem compile all btree source files----------------------------------------------
  113. echo on
  114. tcc -c -O -G -A -C- -m%1 btclose.c  btcreate.c btdelcur.c btdelete.c btfirst.c  btfix.c
  115. tcc -c -O -G -A -C- -m%1 btgetcur.c btgetk.c   btgetlck.c btinsert.c btkeycmp.c btlast.c
  116. tcc -c -O -G -A -C- -m%1 btlock.c   btnext.c   btopen.c   btprev.c   btsearch.c btsetbuf.c
  117. tcc -c -O -G -A -C- -m%1 btsetcur.c btsetvbu.c btsync.c
  118. tcc -c -O -G -A -C- -m%1 btops.c    dgops.c    kyops.c    ndops.c
  119. @echo off
  120.  
  121. rem build the btree library archive---------------------------------------------
  122. if exist btree%1.lib del btree%1.lib
  123. echo on
  124. tlib btree%1 @btree.rsp
  125. @echo off
  126.  
  127. rem install the btree library---------------------------------------------------
  128. if not exist \tc\include\btree.h goto h
  129. echo \tc\include\btree.h exists.  ^C to exit, any other key to continue.
  130. pause
  131. :h
  132. echo on
  133. copy btree.h \tc\include\btree.h
  134. @echo off
  135.  
  136. if not exist \tc\lib\btree%1.lib goto lib
  137. echo \tc\lib\btree%1.lib exists.  ^C to exit, any other key to continue.
  138. pause
  139. :lib
  140. echo on
  141. copy btree%1.lib \tc\lib\btree%1.lib
  142. @echo off
  143.  
  144. rem end of btree installation batch file----------------------------------------
  145. :end
  146.